import flash.display.BitmapData;
import flash.filters.ColorMatrixFilter;
import flash.filters.BlurFilter;
import flash.geom.*;
//
var stagew:Number = Stage.width;
var stageh:Number = Stage.height;
//
var myBitmapData:BitmapData = new BitmapData (stagew, stageh, false, 0xFFFFFF);
var mc:MovieClip = this.createEmptyMovieClip ("mc", this.getNextHighestDepth ());
mc.attachBitmap (myBitmapData, this.getNextHighestDepth ());
//
var myElements_array:Array = [1, 0, 0, 0, 1, 
							  0, 1, 0, 0, 2, 
							  0, 0, 1, 0, 3, 
							  0, 0, 0, 1, 0];
//
var myElementsAlt_array:Array = [1, 0, 0, 0, -5, 
								 0, 1, 0, 0, -10, 
								 0, 0, 1, 0, -15, 
								 0, 0, 0, 1, 0];
//
var myColorMatrix_filter:ColorMatrixFilter = new ColorMatrixFilter (myElements_array);
//
for (var j:Number = 1; j<=16; j++) {
	var fun:MovieClip = this.createEmptyMovieClip ("container", this.getNextHighestDepth ());
	moveThisShit (fun);
}
//
mc.swapDepths (this.getNextHighestDepth ());
//
mc.onEnterFrame = function () {
	myBitmapData.applyFilter (myBitmapData, myBitmapData.rectangle, new Point (0, 0), myColorMatrix_filter);
};
//
mc.onPress = function () {
	var myColorMatrix_filter:ColorMatrixFilter = new ColorMatrixFilter (myElementsAlt_array);
	mc.onEnterFrame = function () {
		myBitmapData.applyFilter (myBitmapData, myBitmapData.rectangle, new Point (0, 0), myColorMatrix_filter);
	};
};
//
mc.onRelease = function () {
	var myColorMatrix_filter:ColorMatrixFilter = new ColorMatrixFilter (myElements_array);
	mc.onEnterFrame = function () {
		myBitmapData.applyFilter (myBitmapData, myBitmapData.rectangle, new Point (0, 0), myColorMatrix_filter);
	};
};
//
function moveThisShit (mc:MovieClip):Void {
	var mover:MovieClip = mc.createEmptyMovieClip ("mover", mc.getNextHighestDepth ());
	//
	mc._x = 0;
	mc._y = stageh*.5;
	//	
	putShape (mover);
	var angles:Array = new Array (90, 90, 180, 0, 270, 270);
	var angles_dif:Array = new Array (Math.random (), Math.random (), Math.random (), Math.random (), Math.random (), Math.random ());
	mc.onEnterFrame = function () {
		var newAngle:Number = 0;
		for (var i:Number = 0; i<angles.length; i++) {
			newAngle += Math.sin (angles[i]/180*Math.PI)/angles.length;
			angles[i] += angles_dif[i];
		}
		mover._rotation = newAngle*1000;
		var speed:Number = 5*(Math.abs (newAngle)*.85+.15);
		this._x += speed*Math.cos ((mover._rotation)*Math.PI/180);
		this._y += speed*Math.sin ((mover._rotation)*Math.PI/180);
		if (this._x<0) {
			this._x += stagew;
		}
		if (this._y<0) {
			this._y += stageh;
		}
		if (this._x>stagew) {
			this._x -= stagew;
		}
		if (this._y>stageh) {
			this._y -= stageh;
		}
		//te if'y można by jakoś załatwić użwyając modulo...
		var myMatrix:Matrix = new Matrix ();
		myMatrix.rotate (mover._rotation/180*Math.PI);
		var translateMatrix:Matrix = new Matrix ();
		translateMatrix.translate (this._x, this._y);
		myMatrix.concat (translateMatrix);
		myBitmapData.draw (mover, myMatrix);
	};
}
//
function putShape (square_mc:MovieClip):Void {
	square_mc.beginFill (0x001122, 9);
	square_mc.moveTo (-3, -5);
	square_mc.lineTo (-3, 5);
	square_mc.lineTo (5, 5);
	square_mc.lineTo (5, -5);
	square_mc.endFill ();
	square_mc.beginFill (0x003366, 100);
	square_mc.moveTo (-3, -3);
	square_mc.lineTo (-3, 3);
	square_mc.lineTo (3, 3);
	square_mc.lineTo (3, -3);
	square_mc.endFill ();
	square_mc.beginFill (0xffffff);
	square_mc.moveTo (-3, -1);
	square_mc.lineTo (-3, 1);
	square_mc.lineTo (1, 1);
	square_mc.lineTo (1, -1);
	square_mc.endFill ();
}